1 REM THIS PGM WAS ADAPTED FROM A SIMILAR PGM ON A MAINFRAME COMPUTER.  THE
2 REM AUTHOR OF THE ORIGINAL PGM IS UNKNOWN
5 PRINT"[147]WELCOME TO MILLION.":PRINT:PRINT"WOULD YOU LIKE INSTRUCTIONS?[160](Y/N)"
6 GOSUB 260
7 IF A$="N" THEN 100
8 IF A$<>"Y"THEN 6
10 PRINT"[147]THE OBJECT OF THIS GAME IS TO GUESS A NUMBER ";
20 PRINT"BETWEEN 1 & 10000 AS QUICKLY AS POSSIBLE.  THE PROGRAM GIVES YOU ";
25 PRINT"ONE MILLION DOLLARS AT THE BEGINNING OF THE GAME.  EACH TIME YOU MAKE ";
27 PRINT"A GUESS THE PROGRAM WILL TAKE SOME OF YOUR MONEY AWAY FROM YOU.  ";
29 PRINT"THE PROGRAM TAKES MORE MONEY AWAY FOR EACH SECOND IT TAKES YOU TO MAKE ";
31 PRINT"EACH GUESS.  HOWEVER, IT DOESN'T PAY TO BE TOO HASTY BECAUSE EACH ";
33 PRINT"GUESS COSTS PROGRESSIVELY MORE. GOOD LUCK."
100 X=INT(RND(TI)*10000 + 1)
150 DV=2:TI$="000000"
160 MN=1000000:GN=0
170 GN=GN+1:DV=DV+1
171 GOSUB250:GOSUB300
172 IF G% = X THEN PRINT:PRINT:PRINT"YOU GOT IT.[146]":GOSUB320:GOTO183
174 PRINT:PRINT"YOUR GUESS IS TOO ";
175 IF G% < X THEN PRINT"SMALL[146]"
176 IF G% > X THEN PRINT"LARGE[146]"
180 GOSUB 200:GOSUB320
181 IF MN>0 THEN GOTO190
183 PRINT:PRINT"THE NUMBER WAS";X
185 PRINT:PRINT"WOULD YOU LIKE TO PLAY AGAIN? (Y/N)"
186 GOSUB260
187 IF A$="Y" THEN 100
188 IF A$<>"N"THEN 186
189 END
190 GOTO170
200 D3=X/DV: RM=D3-INT(D3): RM=RM+.01
210 RM=INT(RM*DV):PRINT
220 PRINT:PRINT "THE NUMBER DIVIDED BY";DV;"LEAVES A","REMAINDER OF";RM
225 RETURN
250 PRINT:PRINT"PRESS ANY LETTER TO CONTINUE";
251 GETA$:IFA$="" THEN GOTO 251
252 IF ASC(A$)<58 AND ASC(A$) > 47 THEN GOTO 251
254 RETURN
260 GETA$:IFA$="" THEN GOTO 260
261 RETURN
300 INPUT"[147]WHAT IS YOUR GUESS";G%
310 GT=TI:TI$="000000"
315 RETURN
320 MN=MN-(GT/20)*4^GN:REMMONEY = MONEY - GUESS TIME ...
321 REM (IN SECS) * 4 ^ GUESS NUMBER(IE 1ST, 2ND, 3RD, ETC.)
322 IF MN<=0 THENPRINT"YOU HAVE RUN OUT OF MONEY":GOTO330
325 PRINT:PRINT"YOU HAVE";MN;"DOLLARS LEFT"
330 RETURN